返回目录：excel表格制作
Min与MinA函数是 Excel 中用于求最小值的函数，前者用于求数值的最小值，后者用于求数值和逻辑值的最小值。它们都至少要有一个参数，最多只能有 255 个参数。两个函数既可以不加任何条件求最小值又可以用If函数与星号（*）求满足指定条件的最小值。以下就是 Excel Min函数与MinA函数的求最小值的使用方法，共包含5个实例，求不为0最小值、返回最小时间和用if加*组合多条件求最小值，实例操作所用版本均为 Excel 2016。
一、Excel Min函数与MinA函数语法
（一）Min函数语法
表达式：MIN(Number1, [Number2], ...)
中文表达式：MIN(数值1, [数值2], ...)
（二）MinA函数语法
表达式：MINA(Value1,[Value2], ...)
中文表达式：MINA(值1,[值2], ...)
（三） Min函数与MinA函数异同点
Min函数与MinA函数的异同点与Max函数与MaxA函数的异同点一样，可以参数上一篇《Excel Max与MaxA函数的使用方法与用if或*组合多条件求最大值实例》。
二、Excel Min与MinA函数使用的方法及实例
（一）Min函数的使用方法
1、选中 B1 单元格，输入公式 =min(a1:A6)，按回车，返回最小值 5；选中 A4，按 Delete，把 5 删除，B1 返回最小值 8；双击 A2，把 8 改为 "8"，B1 返回最小值 10；选中 A4，输入“二”，B1 返回最小值 10；选中 A4，输入 false，B1 返回最小值 10；选中 A4，把 #VALUE! 复制到 A4，B1 返回值 #VALUE!；操作过程步骤，如图1所示：
图1
2、公式说明：
公式 =min(a1:A6) 用于返回 A1 至 A6 中的最小值；当把 A4 中的 5 删除后，公式返回 8，说明Min函数忽略空单元格；当把 A2 的 8 改为“8”后，公式返回 10，说明单元格中用双引号括起来的数值被忽略；当在 A4 中输入“二”后，公式返回 10，说明不能转为数值的文本被忽略；在 A4 输入 false 后，公式仍返回 10，说明Min函数忽略单元格中的逻辑值；把 #VALUE! 复制到 A4 后，返回值错误 #VALUE!，说明单元格中有错误值，Min函数直接返回错误值。
（二）MinA函数的使用方法
1、双击 B1 单元格，把公式 =MINA(A1:A6,4) 复制到 B1，按回车，返回最小值 4；操作过程步骤，如图2所示：
图2
2、公式 =MINA(A1:A6,4) 返回最小值 4，说明MinA函数的参数可以同时为不同类型，Min函数也一样。
三、Excel Min函数的扩展应用实例
（一）用 Min + If 求不为 0 的最小值
1、假如要求学生“高数”成绩中不为 0 的最低分。双击 C2 单元格，把公式 =MIN(IF(B2:B10>0,B2:B10)) 复制到 C2，按 Ctrl + Shift + 回车，返回不为 0 的最小值 76；操作过程步骤，如图3所示：
图3
2、公式说明：
A、公式 =MIN(IF(B2:B10>0,B2:B10)) 是一个数组公式，因此要按 Ctrl + Shift + 回车。
B、B2:B10>0 是 If 的条件，意思是：如果 B2 至 B10 的值大于 0，返回 True，否则返回 False；例如第一次取 B2 中的值 76，它大于 0，所以返回 True，第二取 B3 中的值 80，它也大于 0，也返回 True；最后返回数组 {TRUE;TRUE;TRUE;FALSE;TRUE;TRUE;TRUE;TRUE;TRUE}。
C、B2:B10 返回数组 {76;80;91;0;87;86;83;87;83}，IF(B2:B10>0,B2:B10) 变为
IF({TRUE;TRUE;TRUE;FALSE;TRUE;TRUE;TRUE;TRUE;TRUE},{76;80;91;0;87;86;83;87;83})，把两个数组对应的元素相乘，返回结果 {76;80;91;FALSE;87;86;83;87;83}，相乘时，True 被当为 1。
D、则公式变为 =MIN({76;80;91;FALSE;87;86;83;87;83})，由于数组中的逻辑值不计入求最小值，所以返回最小值 76。
（二）返回最小时间
1、双击 B1 单元格，把公式 =MIN(--A1:A8) 复制到 B1，按 Ctrl + Shift + 回车，返回最小时间 9:12:35；操作过程步骤，如图4所示：
图4
2、公式说明：
公式 =MIN(--A1:A8) 中 -- 表示把时间转为数值，然后再求最小值。注意：B1 单元格的格式必须是时间类型，否则返回的可能是数值而不是时间。
（三）用 If 和 * 组合多条件求最小值
1、假如要求“产品名称”为“白色T恤”且销量大于等于 800 的服装最早销量日期。双击 E2 单元格，把公式 =MIN(IF((A2:A11="白色T恤")*(D2:D11>=800),B2:B11)) 复制到 E2，按 Ctrl + Shift + 回车，返回服装最早销量日期 2018/9/10；操作过程步骤，如图5所示：
图5
2、公式 =MIN(IF((A2:A11="白色T恤")*(D2:D11>=800),B2:B11)) 说明：
A、(A2:A11="白色T恤") 是 If 的一个条件，意思是：如果 A2 至 A11 中为“白色T恤”的返回 True，否则返回 False，最后返回 {TRUE;FALSE;TRUE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;FALSE}。
B、(D2:D11>=800) 是 If 的另一个条件，意思是：如果 D2 至 D11 中大于等于 800 的返回 True，否则返回 False，最后返回 {FALSE;FALSE;TRUE;FALSE;TRUE;TRUE;FALSE;TRUE;TRUE;TRUE}。
C、则 (A2:A11="白色T恤")*(D2:D11>=800) 变为 {TRUE;FALSE;TRUE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;FALSE}*{FALSE;FALSE;TRUE;FALSE;TRUE;TRUE;FALSE;TRUE;TRUE;TRUE}，把两个数组对应的元素相乘，最后返回 {0;0;1;0;0;1;0;0;0;0}，相乘时，True 被当为 1、False 转为 0。
D、则公式变为 =MIN(IF({0;0;1;0;0;1;0;0;0;0},B2:B11))，条件数组中为 0 的返回 False、为 1 的返回 B2 至 B11 对应的值，则公式变为 =MIN({FALSE;FALSE;43353;FALSE;FALSE;43354;FALSE;FALSE;FALSE;FALSE})，最后求最小值返回 43353，转为日期就是 2018/9/10。
提示：E2 的单元格格式必须为日期，否则显示的不是日期而是数字。
3、不能把公式 =MIN(IF((A2:A11="白色T恤")*(D2:D11>=800),B2:B11)) 改为 =MIN((A2:A11="白色T恤")*(D2:D11>=800)*(B2:B11))，它们不等价，后者会返回意外值 1900/1/0，如图6所示：
图6